Détecteur capacitif

De Wikidebrouillard.

Version actuelle en date du 5 août 2013 à 18:02

Présentation de l'expérience

Un détecteur capacitif permet de détecter une pression sur une surface conductrice. Nous prendrons ici comme exemple une feuille de papier avec des touches dessinées au crayon gris.

Matériel

• Une résistance de 1 MOhm
• Une LED
• Buzzer
• Un Ordinateur
• Le logiciel Arduino
• Une carte arduino
• Une feuille de papier
• Une breadboard
• Un crayon gris

L'expérience

La manipulation

• Réaliser le montage suivant :

• Sur une feuille de papier, dessiner des touches au crayon gris en insistant bien afin, que le graphite se dépose convenablement. Ces traits doivent rejoindre l’extrémité de la feuille.

Exemple de la feuille de papier reliée au circuit :

• Entrer le code suivant dans le logiciel arduino :

// Pin à connecter à la LED
int LEDPin = 13;
// Pin à connecter à la feuille de papier
int capSensePin = 2;
// Seuil de détection du capteur, à régler par essais
int touchedCutoff = 60;

void setup(){
  Serial.begin(9600);
  // Mise en place de la LED
  pinMode(LEDPin, OUTPUT);
  digitalWrite(LEDPin, LOW);
}


void buzz(int targetPin, long frequency, long length) {
  long delayValue = 1000000/frequency/2;
  long numCycles = frequency * length/ 1000;
  for (long i=0; i < numCycles; i++)
  {
    digitalWrite(targetPin,HIGH);
    delayMicroseconds(delayValue);
    digitalWrite(targetPin,LOW);
    delayMicroseconds(delayValue);
  }
}


void loop(){
  
  // Si le capteur atteint un certain seuil de tension, la led s'allume
  
  if (readCapacitivePin(capSensePin) > touchedCutoff) {
    digitalWrite(LEDPin, HIGH);
    // utilisation
    buzz(4, 2500, 1000); // buzz sur pin 4 à 2500Hz
  }
  else {
    digitalWrite(LEDPin, LOW);
  }
  
  // Affiche toutes les 500 millisecondes la valeur du capteur
  if ( (millis() % 500) == 0){
    Serial.print("Capacitive Sensor on Pin 2 reads: ");
    Serial.println(readCapacitivePin(capSensePin));
  }
}

// readCapacitivePin
//  Entrée: Arduino pin number
//  Sortie: Un nombre, de 0 à 17, représentant la capacité.
//  Lorsqu'on touche la sortie (ou quoi que ce soit attache), le nombre va augmenter
uint8_t readCapacitivePin(int pinToMeasure){
  // This is how you declare a variable which
  //  will hold the PORT, PIN, and DDR registers
  //  on an AVR
  volatile uint8_t* port;
  volatile uint8_t* ddr;
  volatile uint8_t* pin;
  // Here we translate the input pin number from
  //  Arduino pin number to the AVR PORT, PIN, DDR,
  //  and which bit of those registers we care about.
  byte bitmask;
  if ((pinToMeasure >= 0) && (pinToMeasure <= 7)){
    port = &PORTD;
    ddr = &DDRD;
    bitmask = 1 << pinToMeasure;
    pin = &PIND;
  }
  if ((pinToMeasure > 7) && (pinToMeasure <= 13)){
    port = &PORTB;
    ddr = &DDRB;
    bitmask = 1 << (pinToMeasure - 8);
    pin = &PINB;
  }
  if ((pinToMeasure > 13) && (pinToMeasure <= 19)){
    port = &PORTC;
    ddr = &DDRC;
    bitmask = 1 << (pinToMeasure - 13);
    pin = &PINC;
  }
  // Discharge the pin first by setting it low and output
  *port &= ~(bitmask);
  *ddr  |= bitmask;
  delay(1);
  // Make the pin an input WITHOUT the internal pull-up on
  *ddr &= ~(bitmask);
  // Now see how long the pin to get pulled up
  int cycles = 16000;
  for(int i = 0; i < cycles; i++){
    if (*pin & bitmask){
      cycles = i;
      break;
    }
  }
  // Discharge the pin again by setting it low and output
  //  It's important to leave the pins low if you want to 
  //  be able to touch more than 1 sensor at a time - if
  //  the sensor is left pulled high, when you touch
  //  two sensors, your body will transfer the charge between
  //  sensors.
  *port &= ~(bitmask);
  *ddr  |= bitmask;
  
  return cycles;
}

• Appuyer sur les touches.

Que voit-on ?

Lorsqu'on appuie sur la surface conductrice utilisée dans le montage, la LED s'allume et on entend un bruit de buzzer.

Explications

De manière simple

La pression du doigt fait varier la tension dans la surface conductrice. Cette variation est détectée par l'arduino, qui allume alors la LED et déclenche le buzzer.

Allons plus loin dans l'explication

En démarrant le montage, on charge électriquement la surface conductrice pour l'amener à un potentiel. Lorsqu'on touche la surface en question, le corps agit comme une capacité et décharge la plaque, ce qui réduit le potentiel sur la surface.

Catégories

Détecteur capacitif