Grove : Capteur d'Ã©lectricitÃ©

De Wikidebrouillard.

Sommaire

1 Introduction
2 Caractéristiques
3 Suggestions d'utilisation
4 Caractéristiques techniques
5 Principales caractéristiques techniques
6 Caractéristiques électroniques
7 Utilisation
8 Ressources
9 Aller plus loin
10 Crédits

Introduction

Le capteur d’électricité fait partie des modules Grove. Il fonctionne à partir d'un transformateur de courant TA12-200 qui convertit le courant alternatif en courant de plus faible amplitude. Il permet de tester d'importants courants électriques alternatifs, jusqu'à 5 A.

Modèle :SEN23931P

Caractéristiques

Interface compatible Grove
Alimentation maximale: 5 A
Haute précision
Taille réduite

Suggestions d'utilisation

Mesure du courant alternatif
Contrôle de l'état d'un appareil

Caractéristiques techniques

Principales caractéristiques techniques

Éléments	Min
Taille du PCB	2,0 cm x 4,0 cm
Interface	Écartement des broches 2,0 mm
Structure I/O (entrée/sortie)	SIG,NC,NC,GND
ROHS	OUI

Caractéristiques électroniques

Éléments	Min	Normal	Max.	Unité
Rapport de transformation	-	2000:1	-	-
Courant d'entrée	0	-	5	A
Courant de sortie	0	-	2,5	mA
Résistance d'échantillonnage	-	800	-	Ω
Tension d’échantillonnage	0	-	2	V
Fréquence de travail	20	-	20 K	HZ
Échelle non-linéaire	-	-	0,2 %	-
Déphasage	-	-	5'	-
Température de fonctionnement	-55	-	85	℃
Rigidité diélectrique	-	6	-	KVAC/1 min

Utilisation

Le schéma qui suit illustre l'utilisation de la mesure d'amplitude d'un courant alternatif. La broche SIG délivre une tension alternative basée sur le courant alternatif mesuré. Il est possible de mesurer la valeur en utilisant un convertisseur A/N (analogique-numérique).

Connecter le module à l'entrée analogue A0 de Grove - Base board
Mettre le fil du courant alternatif dans le trou du transformateur de courant.

Copier et coller le code ci-dessous dans un nouveau programme Arduino.

/****************************************************************************/	
//	Fonction : mesure l'amplitude du courant alternatif et 
//			 la valeur effective du courant alternatif sinusoïdal.
//	matériel : capteur d'électricité Grove		
//	Date: 	 19 jan. 2013
//	par www.seeedstudio.com
#define ELECTRICITY_SENSOR A0 // La broche d'entrée analogique à laquelle le capteur est raccordé

float amplitude_current;               // amplitude du courant
float effective_value;       // courant effectif 

void setup() 
{
	Serial.begin(9600); 
	pins_init();
}
void loop() 
{
	int sensor_max;
	sensor_max = getMaxValue();
	Serial.print("sensor_max = ");
	Serial.println(sensor_max);
	//La valeur de la Vcc sur l'interface Grove du capteur est de 5 V.
	amplitude_current=(float)sensor_max/1024*5/800*2000000;
	effective_value=amplitude_current/1.414;//minimum_current=1/1024*5/800*2000000/1.414=8.6(mA) 
						// Uniquement pour le courant alternatif sinusoïdal
	Serial.println("The amplitude of the current is(in mA)");
	Serial.println(amplitude_current,1);// Seulement un chiffre après la virgule
	Serial.println("The effective value of the current is(in mA)");
	Serial.println(effective_value,1);
}
void pins_init()
{
	pinMode(ELECTRICITY_SENSOR, INPUT);
}
/*Fonction : échantillonne sur 1000 ms et obtient la valeur maximale de la broche SIG*/
int getMaxValue()
{
	int sensorValue;             // valeur restituée par le capteur
	int sensorMax = 0;
	uint32_t start_time = millis();
	while((millis()-start_time) < 1000)//sample for 1000ms
	{
		sensorValue = analogRead(ELECTRICITY_SENSOR);
		if (sensorValue > sensorMax) 
		{
			/*enregistre la valeur maximale du capteur*/
			sensorMax = sensorValue;
		}
	}
	return sensorMax;
}

Télécharger le code. Si vous ne savez pas comment faire, cliquez ici.

Remarque : le courant effectif minimum capté par le code peut être calculé en utilisant l'équation suivante. minimum_current=1/1024*5/800*2000000/1.414=8.6(mA).